Musica en ejecutables???

[LantraX]

Analisando un poco un patch, me encontre que usaba una musica de fondo.... quisiera saber como es posible esto y que tipo de musica es?? En lo posible quisiera que me mandaran un ejemplo en VB.... Gracias....

[MaN!FesT]

Bueno este ejemplo no se donde lo encontre (no es mío) pero pues me ha servido reproduce .wav, hay te lo dejó haber si te sirve:

Agregas un text, 2 command, y un common dialog:

Código:

' Constantes para los flags

'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''

'  look for application specific association
Private Const SND_APPLICATION = &H80
'  name is a WIN.INI [sounds] entry
Private Const SND_ALIAS = &H10000
'  name is a WIN.INI [sounds] entry identifier
Private Const SND_ALIAS_ID = &H110000
'  play asynchronously
Private Const SND_ASYNC = &H1
  '  play synchronously (default)
Private Const SND_SYNC = &H0

'  name is a file name
Private Const SND_FILENAME = &H20000
'  loop the sound until next sndPlaySound
Private Const SND_LOOP = &H8
'  lpszSoundName points to a memory file
Private Const SND_MEMORY = &H4
'  silence not default, if sound not found
Private Const SND_NODEFAULT = &H2
 '  don't stop any currently playing sound
Private Const SND_NOSTOP = &H10
 '  don't wait if the driver is busy
Private Const SND_NOWAIT = &H2000
 '  purge non-static events for task
Private Const SND_PURGE = &H40
 '  name is a resource name or atom
Private Const SND_RESOURCE = &H40004

' Declaración del api PlaySound
'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
Private Declare Function PlaySound Lib "winmm.dll" Alias "PlaySoundA" ( _
    ByVal lpszName As String, _
    ByVal hModule As Long, _
    ByVal dwFlags As Long) As Long

Private Sub Command1_Click()
    With CommonDialog1
        .DialogTitle = " Seleccionar archivo de audio"
        ' Filtra los Archivos con extensión wav
        .Filter = "Archivos wav|*.wav"
       
        ' Abre el diálogo
        .ShowOpen
       
        If .FileName = vbNullString Then
            Exit Sub
        Else
            Text1.Text = .FileName
        End If
    End With
   
End Sub

' Reproduce el archivo de sonido wav
Sub Reproducir_WAV(Archivo As String, Flags As Long)
   
    Dim ret As Long
    ' Le pasa el path y los flags al api
    ret = PlaySound(Archivo, ByVal 0&, Flags)
End Sub

' Botón para reproducir el sonido
Private Sub Command2_Click()
   
    Call Reproducir_WAV(Text1.Text, SND_FILENAME Or SND_ASYNC Or SND_NODEFAULT)
End Sub

Private Sub Form_Load()
   
    Command1.Caption = "Abrir archivo "
    Command2.Caption = "Reproducir"
    Me.Caption = "PlaySound"
End Sub
 

[zXxOsirisxXz]

Bueno, yo lo ise con el Component de Windows Media Player.

solo vas a Project>Components y escojes Windows Media Player.

luego, pon el windows media player dentro de tu formulario.

y en el form_load () pones..

WindowsMediaPl ayer1.settings .autoStart = False 'Esto si kieres k el programa NO corra la musica en cuanto se ejecute
WindowsMediaPl ayer1.URL = " Ruta de la Musica, si esta en el mismo folder, solo pones el nombre"
WindowsMediaPl ayer1.settings .setMode ("Loop"), True 'Esto si kieres k la musica se repita en cuanto termine
WindowsMediaPl ayer1.settings .volume = 100 'El volumen, basado en 0~100

En caso de k lo kieras invisible y k ponga la musica.ps solo agrega esto en el formload igual..

windowsmediapl ayer1.controls .play

Espero k te haya servido de algo.

Salu2