Bases en DBF

[sirhamelef]

Hola muchachos, necesito empezar a manipular bases en formato dbf utilizando Visual Basic 6, quisiera tambien saber si se puede utilizar SQL desde el VB6 sobre las bases que antes le comente. No tengo ni idea por donde empezar si alguien me dice si esto es posible se lo agradecería.

Muchas gracias
Eze

[ranefi]

Hola sirhamelef, buena tarde. Aquí te dejo el código necesario para manipular bases de datos de Fox Pro.

Agregar 4 controles CommandButton, 1 arreglo de 4 TextBox e REPLACEar el siguiente código

Código:

Public FoxCon As ADODB.Connection
Public FoxRec As ADODB.Recordset

Public NombreBD As String
Public RutaBD As String



Private Sub Command1_Click()
    PrimerRegistro
End Sub

Private Sub Command2_Click()
    RegistroAnterior
End Sub

Private Sub Command3_Click()
    RegistroSiguiente
End Sub

Private Sub Command4_Click()
    UltimoRegistro
End Sub

Private Sub Form_Load()
    AbrirBD
End Sub

Public Sub AbreFox()
    RutaBD = App.Path
    Set FoxCon = New ADODB.Connection
    Set FoxRec = New ADODB.Recordset
   
    FoxCon.Open ("Driver=Microsoft Visual FoxPro Driver;" & _
        "UID=;SourceType=DBF;SourceDB=" & RutaBD)
End Sub

Public Sub AbrirBD()
    NombreBD = "Tabla1.dbf"
   
    AbreFox
   
    With FoxRec
        .CursorType = 0
        .CursorLocation = 2
        .LockType = 1
   
        .Open "SELECT * FROM " & NombreBD, _
            FoxCon, adOpenDynamic, adLockBatchOptimistic
        .MoveFirst 'PA' CORREGIR EL ERROR DE SALTO
    End With
   
    With Me
        Dim CuadrosTexto As TextBox
       
        For Each CuadrosTexto In .Text1
            Set CuadrosTexto.DataSource = FoxRec
        Next
       
        .Text1(0).DataField = "campo1"
        .Text1(1).DataField = "campo2"
        .Text1(2).DataField = "campo3"
        .Text1(3).DataField = "campo4"
    End With
End Sub

Public Sub CerrarFox()
    FoxCon.Close
   
    Set FoxCon = Nothing
    Set FoxRec = Nothing
End Sub

Private Sub Form_Unload(Cancel As Integer)
    CerrarFox
End Sub

Public Sub PrimerRegistro()
    FoxRec.MoveFirst
End Sub

Public Sub UltimoRegistro()
    FoxRec.MoveLast
End Sub

Public Sub RegistroAnterior()
    With FoxRec
        .MovePrevious
       
        If .BOF Then
            .MoveFirst
        End If
    End With
End Sub

Public Sub RegistroSiguiente()
    With FoxRec
        .MoveNext
       
        If .EOF Then
            .MoveLast
        End If
    End With
End Sub

Espero te sea de utilidad.

NOTA: El arreglo se crea copiando y pegando los controles TextBox de tal forma que te queden 4 controles TextBox.

NOTA2: ¡Ah! Casi se me olvida, deberás crear una tabla llamada Tabla1.dbf con los siguientes campos:

• Campo1
• Campo2
• Campo3
• Campo4

Dicha tabla deberá de encontrarse en la misma ruta de la aplicación. Con respecto a SQL creo que ya habrás notado que en el código se utiliza algo de SQL.